/* $VER: 1.0, ©1996 Dietmar Eilert. Create empty table */

OPTIONS RESULTS                             /* enable return codes     */

if (LEFT(ADDRESS(), 6) ~= "GOLDED") then    /* not started by GoldEd ? */
    address 'GOLDED.1'

'LOCK CURRENT RELEASE=4'                    /* lock GUI, gain access   */
if (RC ~= 0) then
    exit

OPTIONS FAILAT 6                            /* ignore warnings         */
SIGNAL ON SYNTAX                            /* ensure clean exit       */

/* ------------------------ INSERT YOUR CODE HERE: ------------------- */

'QUERY DOC VAR=DOC'

'FIX VAR=DOC'

'SUFFIX STRING="' || DOC || '" SUFFIX=".html"'

'NAME NEW=' || RESULT

'REQUEST STRING TITLE="Create new table" BODY="Table caption         " OLD="Title" VAR=CAPTION'

if (RC = 0) then do

    'REQUEST LONG TITLE="Create new table" BODY="Number of columns     " MIN=1 MAX=255 OLD=2 VAR=COLUMNS'

    if (RC = 0) then do

        'REQUEST LONG TITLE="Create new table" BODY="Number of rows        " MIN=1 MAX=255 OLD=2 VAR=ROWS'

        if (RC = 0) then do

            'REQUEST TITLE="Create new table" BODY="Should the table have a border ?" BUTTON="!BORDER|NoBorder|_Cancel" VAR=BORDER'

            if ((RC = 0) & (RESULT ~= 0)) then do

                'REQUEST TITLE="Create new table" BODY="Should the first row be a table header ?" BUTTON="!HEADER|_Data|_Cancel" VAR=HEADER'

                if ((RC = 0) & (RESULT ~= 0)) then do

                    'INSERT LINE'
                    'INSERT LINE'
                    'DOWN'

                    if (BORDER = 1) then
                        'TEXT STAY T="<TABLE BORDER>"'
                    else
                        'TEXT STAY T="<TABLE>"'

                    'DOWN'
                    'INSERT LINE'
                    'TEXT STAY T="</TABLE>"'

                    if (CAPTION ~= "") then do

                        'FIX VAR=CAPTION'

                        'INSERT LINE'
                        'TEXT STAY T="<CAPTION>"'
                        'DOWN'

                        'INSERT LINE'
                        'TEXT STAY T="' || CAPTION || '"'
                        'DOWN'

                        'INSERT LINE'
                        'TEXT STAY T="</CAPTION>"'
                        'DOWN'
                    end

                    do ROW = 1 to ROWS

                        'INSERT LINE'
                        'TEXT STAY T="<RD>"'
                        'DOWN'

                        if (ROW = 1) then
                            'PING SLOT=0'

                        if ((ROW = 1) & (HEADER = 1)) then do

                            do COLUMN = 1 to COLUMNS

                                'INSERT LINE'
                                'TEXT STAY T="<TH>header cell</TH>"'
                                'DOWN'

                            end
                        end
                        else do

                            do COLUMN = 1 to COLUMNS

                                'INSERT LINE'
                                'TEXT STAY T="<TD>table cell</TD>"'
                                'DOWN'

                            end
                        end

                        'INSERT LINE'
                        'TEXT STAY T="</RD>"'
                        'DOWN'
                    end

                    'PONG SLOT 0'

                    'GOTO STEP=4'

                    'REQUEST STATUS="Edit the cell''s text"'
                end
            end
        end
    end
end

/* ---------------------------- END OF YOUR CODE --------------------- */

'UNLOCK' /* VERY important: unlock GUI */
EXIT

SYNTAX:

SAY "Sorry, error line" SIGL ":" ERRORTEXT(RC) ":-("
'UNLOCK'
EXIT